# SPDX-FileCopyrightText: 2024 Lubin Bailly <lubin.bailly@dgnum.eu>
#
# SPDX-License-Identifier: EUPL-1.2

{
  config,
  lib,
  pkgs,
  name,
  ...
}:

let
  inherit (lib) mapAttrs mkOption;

  inherit (lib.types)
    attrs
    attrsOf
    bool
    str
    submodule
    package
    ;

  mandatory.options = {
    supportPoE = mkOption {
      type = bool;
      example = true;
      description = ''
        Whether this interface supports PoE.
      '';
    };
  };
in
{
  imports = [
    ./interfaces.nix
    ./poe.nix
    ./protocols.nix
    ./system.nix
    ./vlans.nix
  ];

  options = {
    # Hack because of this https://git.dgnum.eu/DGNum/colmena/src/commit/71b1b660f2cda2e34e134d0028cafbd56bb22008/src/nix/hive/eval.nix#L166 which defines nixpkgs option but we don't have it here. What about liminix ?
    nixpkgs = mkOption {
      type = attrs;
      default = { };
      visible = false;
    };
    netconf = {
      xmls.configuration = mkOption {
        type = str;
        readOnly = true;
        description = ''
          The full configuration to send to a JunOS.
        '';
      };
      mandatoryInterfaces = mkOption {
        type = attrsOf (submodule mandatory);
        example = {
          "ge-0/0/0" = {
            supportPoE = true;
          };
          "ge-0/0/1" = {
            supportPoE = true;
          };
          "xe-0/0/0" = {
            supportPoE = false;
          };
        };
        description = ''
          JunOS require some interfaces to always be configured (even if they are disabled),
          which correspond to physical interfaces of the switch. They have to be declared here
          with some information about it (only if it supports PoE for now).
        '';
      };
      rpc = mkOption {
        type = package;
        readOnly = true;
        description = ''
          The final rpc xml to send via netconf.
        '';
      };
    };
  };
  config = {
    interfaces =
      let
        mkIntf = _: _: { };
      in
      mapAttrs mkIntf config.netconf.mandatoryInterfaces;
    netconf = {
      xmls.configuration = with config.netconf.xmls; ''
        <configuration>
          ${system}
          ${interfaces}
          ${protocols}
          ${vlans}
          ${poe}
        </configuration>
      '';
      rpc = pkgs.writeText "${name}.rpc" ''
        <rpc>
          <edit-config>
            <config>
              ${config.netconf.xmls.configuration}
            </config>
            <target>
              <candidate/>
            </target>
          </edit-config>
        </rpc>
        <rpc>
          <commit/>
        </rpc>
      '';
    };
  };
}